如何将股票软件的指标公式修改为选股公式

一、思路

采用反向思维,需要什么条件就先看什么条件,比如图标选股、买入提示选股、上穿等等;然后依照这句公式中需要的条件往前找,删掉不相干的语句;接着按照下面的方法修改公式。这样就基本成功了,多操作几遍就会掌握技巧。

二、详细步骤

1、将公式中的 : 改为 :=

因为选股公式只能输出1个条件式,,故要先将公式中所有的显示式: 改为不显示式:=,如果原来显示式后面接有线型描述(颜色、对齐等)也一并删除。

例如:

ma1:ma(c,5),colorred;
ma2:ma(c,10),colorgreen,POINTDOT;

修改为:

ma1:=ma(c,5),colorred;
ma2:=ma(c,10),colorgreen,POINTDOT;

2、找出选股条件,并写成选股式引用

条件的寻找方法,根据不同的目的,大致分为以下几种:

(1)“字”选股,如“买”选股

方法:先找出公式中出现有“字”的地方,该式开头会以DRAW..TEXT开头,如:DRAWTEXT、DRAWTEXTEX、DRAWYITEXT、DRAWFLAGTEXT、DRAWMOVETEXT。找到后,该函数(条件, ,'字')后面括号内的第1个即为条件,将该条件复制出来并加上分号即可。

例如:
{求'5日均>10日均'选股}

ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWTEXT(ma1>ma2,ma1,'5日均>10日均');

修改为:

ma1:=ma(c,5);
ma2:=ma(c,10);
ma1>ma2;
(2)图标选股,如笑脸选股

方法:先依不同软件,找出该图标的代号,再找出公式中出现DRAWICON函数(条件,   ,图标代号)的式子,对照图标的代号(括号内的第3个),如果该图标代号为所求代号,该函数后面括号内的第1个即为条件,将该条件复制出来并加上分号即可。

例如:
{求图标1选股}

ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWicon(ma1>ma2,ma1,1);

修改为:

ma1:=ma(c,5);
ma2:=ma(c,10);
ma1>ma2;
(3)A线上穿(下穿)B线选股  {上穿--金叉,下穿--死叉}

方法:
A线上穿B线:  cross(A,B);
A线下穿B线:  cross(B,A);

例如:
{求ma1上穿ma2选股}

ma1:ma(c,5);
ma2:ma(c,10);

修改为:

ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma1,ma2);

{求ma1下穿ma2选股}

ma1:ma(c,5);
ma2:ma(c,10);

修改为

ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma2,ma1);
(4)线A上穿(下穿) 选股

方法:
线A上穿:
cross(A,ma(A,2));  或  cross(A,ref(A,1));
线A下穿:
cross(ma(A,2),A);  或  cross(ref(A,1),A);

例如:
{求改成ma1上穿}

ma1:ma(c,5);

修改为

ma1:=ma(c,5);
cross(ma1,ma(ma1,2));
或
ma1:=ma(c,5);
cross(ma1,ref(ma1,1));

{求改成ma1下穿}

ma1:ma(c,5);

修改为:

ma1:=ma(c,5);
cross(ma(ma1,2),ma1);
或
ma1:=ma(c,5);
cross(ref(ma1,1),ma1);
(5)第1次出现条件A选股

方法:先找出条件A,再利用cross(A,0.5);

例如:
{求改成出现图标1选股}

ma1:=ma(c,5);
ma2:=ma(c,10);
DRAWicon(ma1>ma2,ma1,1);

修改为:

方法1:
ma1:=ma(c,5);
ma2:=ma(c,10);
A:=ma1>ma2;
cross(A,0.5);

方法2:直接将条件A写入
ma1:=ma(c,5);
ma2:=ma(c,10);
cross(ma1>ma2,0.5);
(6)线变色选股

如:黄线变红色选股(指标线为黄线,再利用函数变红色线)

方法:先依不同软件,找出条件A,再用cross(A,0.5);

A、飞狐

条件在PARTLINE(条件A, ),colorred;
括号内的第1个即为条件,将该条件复制出来并加上分号即可。

例如:
{求黄线变红色选股}

ma1:ma(c,5),coloryellow;
PARTLINE(ma1>REF(ma1,1),ma1),colorred;

修改为:

ma1:=ma(c,5);
A:=ma1>REF(ma1,1);cross(A,0.5);

B、大智慧L2.分析家

条件在PARTLINE(  ,条件A,rgb(255,0,0),  , ...);
括号内为rgb(255,0,0)的前1个即为条件,将该条件复制出来并加上分号即可。

例如:
{求黄线变红色选股}

ma1:=ma(c,5);
PARTLINE(ma1,ma1>REF(ma1,1),rgb(255,0,0),1,rgb(255,255,0));

修改为:

ma1:=ma(c,5);
A:=ma1>REF(ma1,1);
cross(A,0.5);

C、通达信

条件在IF(条件A,   ,DRAWNULL),colorred;
括号内的第1个即为条件,将该条件复制出来并加上分号即可。

例如:
{求黄线变红色选股}

MA1:MA(C,5),COLORYELLOW;
IF(MA1>REF(MA1,1),MA1,DRAWNULL),COLORRED;

修改为:

MA1:=MA(C,5);
A:=MA1>REF(MA1,1);CROSS(MA1>REF(MA1,1),0.5);
(7)颜色柱选股

方法:先找出公式中出现有STICKLINE函数的地方;找到后,核对该函数后面的颜色,是否为所求颜色:若颜色相同,则括号内的第1个即为条件A,将该条件复制出来并加上分号即可。

例如:
{求红色柱选股}

STICKLINE(c>o,h,l,0.8,1),colorred;

修改为:

A:c>o;

{求第1次红色柱选股}

STICKLINE(c>o,h,l,0.8,1),colorred;

修改为:

A:=c>o;cross(A,0.5);

3、将所有绘图函数及单一输出值(如 0;  k;  if(,,); )全删除,使公式只剩1个选股式输出即可。

若有2个以上条件,条件同时成立时,可在条件间用and连接;

若有2个以上条件,允许条件不同时成立时,可在条件间用or连接。

评论

Your email address will not be published. Required fields are marked *

Scroll Up